home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Monster Media 1996 #14
/
Monster Media No. 14 (April 1996) (Monster Media, Inc.).ISO
/
rem_acc
/
q_a4ra11.zip
/
FRONTEND.Q&A
< prev
next >
Wrap
Text File
|
1996-02-04
|
29KB
|
1,173 lines
▄█████▄ ▄▀▀▄ ▄█████▄ ▐█ ██ ██████▄ ▄█████▄
██ ██ ▀▄▄▀ ██▄▄▄██ ██▄▄██▄ ██ ██ ██▄▄▄██
██ ▀▄██ ▄▀ ▀▄▀ ██▀▀▀██ ▀▀▀▀██▀ ██████ ██▀▀▀██
▀████▀▄ ▀▄ ▄▀▄ ██ ██ ██ ██ ▀██ ██ ██
▀▀ ▀
Revision 11
Questions and Answers for RemoteAccess 2.x
░░▒▒▓▓ FRONTEND.Q&A ▓▓▒▒░░
Updated on 02/04/96
By: Eric Staufer
The Concession Stand
FidoNet 1:374/6568
Setups for the following frontend mailers with RA:
* FrontDoor Setup with RemoteAccess
* D'Bridge Setup with RemoteAccess
* InterMail Setup with RemoteAccess
* Binkley Term with RemoteAccess and OS/2
░▒▓█ FrontDoor Setup with RemoteAccess █▓▒░
Here is The Concession Stand's batch file on how to run RemoteAccess,
FrontDoor, FastEcho, and RATick.
@Echo Off
:START
echo atm0h0d; >>Com1
cd\ra
RA -m\FD\FD.EXE*M -E35
if errorlevel 150 goto SYSMAINT
if errorlevel 100 goto UNPACK
if errorlevel 76 goto RATICK
if errorlevel 35 goto START
if errorlevel 10 goto END
if errorlevel 4 goto ECHO
if errorlevel 3 goto NETMAIL
if errorlevel 2 goto LOCAL
if errorlevel 0 goto START
goto END
:SYSMAINT
echo atm0h1 >>Com1
cd\ra
rauser -S -P
goto START
:UNPACK
if exist c:\fd\file\*.SU* goto TOSSIT
if exist c:\fd\file\*.MO* goto TOSSIT
if exist c:\fd\file\*.TU* goto TOSSIT
if exist c:\fd\file\*.WE* goto TOSSIT
if exist c:\fd\file\*.TH* goto TOSSIT
if exist c:\fd\file\*.FR* goto TOSSIT
if exist c:\fd\file\*.SA* goto TOSSIT
if exist c:\fd\file\*.tic goto RATICK
goto START
:TOSSIT
echo atm0h1 >>Com1
cd\fd\fastecho
fastecho toss
cd\ra
ramsg link -clean -hudson
ramsg pack -purge -delete -recover -renumber -overwrite -link
if exist c:\fd\file\*.tic goto RATICK
echo atm0h0d; >>com1
goto START
:RATICK
cd\ra\ratick
ratick
cd\fd
goto START
:ECHO
cd\fd\fastecho
fastecho scan
cd\fd
goto START
:LOCAL
Echo ATM0H1 >>com1
RA -L -E35
Echo atm0h0d; >>Com1
goto START
:NETMAIL
cd\fd\fastecho
fastecho scan
cd\fd
goto START
:END
Echo:
Echo: Calling up BBS in 5 seconds, press CTRL-C to abort.
Echo:
wait 5
bbs
here is Stu Grant's Multinode Batch file for FrontDoor, RemoteAccess, and
FMail.
-=- The easiest setup to get to the shell to mailer mode is -=-
RA -m\fd\fd.exe*m -E20
-*- This calls up RemoteAccess and tells it to shell to FrontDoor
to wait for the caller, swapping memory and exits at the errorlevel
of 20. Make sure that your Errorlevels match up with FDSETUP
and the RACONFIG. -*-
Batch file to run 1 node, with maintenance for some programs.
@echo off
:: echo on (for debug)
cls
::
:: The Hole BBS (Node 1)
:: Written by Sysop: Stu Grant
::
:: The BAT files to run Node 2 and the Local Node are very simple and
:: incorporate only the first part of this one. Node 2 needs only to
:: exit with an errorlevel at Midnight and check for the MAINT.FLG and
:: then loop until this one is finished running Maint (see midnight).
::
:: Here it is!
::
:: ---- This sets up the Multiline Chat Door -----
cd\ra\doors\chat
cmsetup /R
:: ----- Fire up the Fossil for a DV Window ----
:: c:\ra\bnu.com /f+ /m- /l0:19200
:: ---- Let's Start The BBS (Node 1) ----
:start
c:
cls
echo ath0 >com1
echo Firing up The Hole Node 1 ....
:: ---- Let's set the environments
cd\ra\line1
set ra=c:\ra
set fd=c:\fd
set dszlog=c:\ra\dsz.log
set dszport=0
:: ---- Condition checks and actions ----
cd c:\fd\file
if exist c:\ra\line1\dsz.log del \ra\line1\dsz.log
if exist c:\fd\file\*.tic del *.tic
if exist nodediff.* goto newnode
if exist bre804.* goto bre
if exist rushnet.* goto rush
if exist c:\fd\file\update.ffs goto update
if exist c:\ra\working\*.dat del c:\ra\working\*.dat
:: ---- Fire up RA and Shell to FrontEnd Mailer ----
cd \ra\line1
ra -m\fd\fd.exe*m -e20
:: ---- Errorlevels to trap for action -----
if errorlevel 93 goto midnight
if errorlevel 38 goto unpackmail
if errorlevel 20 goto start
if errorlevel 15 goto reboot
if errorlevel 10 goto out
if errorlevel 5 goto both
if errorlevel 4 goto echo
if errorlevel 3 goto net
if errorlevel 2 goto restart_ra
if errorlevel 1 goto start
if errorlevel O goto start
:: ---- Next Line in case an errorlevel was missed -----
goto start
:: ---- Log back on after type 15 with errorlevel, See docs! ----
:restart_ra
echo ath0 >com1
c:
cd \ra\line1
ra -r -g -e20
if errorlevel 93 goto midnight
if errorlevel 38 goto unpackmail
if errorlevel 20 goto start
if errorlevel 15 goto reboot
if errorlevel 10 goto out
if errorlevel 5 goto both
if errorlevel 4 goto echo
if errorlevel 3 goto net
if errorlevel 1 goto start
if errorlevel O goto start
goto start
:: ---- Scan for Mail after Logoff if EchoMail entered ----
:echo
echo ath1 >com1
fmail scan
goto start
:: ---- Scan for Mail after Logoff if Echo AND NetMail entered ----
:both
echo ath1 >com1
fmail scan
goto start
:: ---- Export NetMail to folder after logoff ----
:net
echo ath1 >com1
cd \ra
mbutil export
goto start
:: ---- This handles updates for FFS ----
:update
echo ath1 >com1
if exist update.* pkunzip -o update.* c:\ra\doors\findfile
if exist update.* del update.*
goto start
:: ---- Unpack and Toss incomming Mail packets ----
:unpackmail
echo ath1 >com1
cd c:\fd\fmail
fmail toss import
goto start
:: ---- Process the various Nodediffs when received ----
:newnode
echo ath1 >com1
cd c:\fd\file
copy nodediff.* c:\fd\fido
pkunpak -r nodediff.* c:\fd\nodelist
del c:\fd\file\nodediff.*
goto start
:bre
echo ath1 >com1
cd\fd\file
copy bre804.* c:\fd\fido
pkunpak -r bre804.* c:\fd\nodelist
del C:\fd\file\bre804.*
goto start
:rush
echo ath1 >com1
cd\fd\file
copy rushnet.* c:\fd\fido
pkunpak -r rushnet.* c:\fd\nodelist
del c:\fd\file\rushnet.*
goto start
::
:: ---- This attempts to handle INIT failures by FrontDoor ----
:: ---- Since I run under OS/2 I must attempt to re-init ----
:: ---- the modem. Under DOS or DV I would run a COLD BOOT ---
:: ---- program. Such as REBOOT.EXE
::
:reboot
cls
echo System Attempting to Re-initialize the Modem.....
echo ATH0 >COM1
delay 10
echo ATH1 >COM1
delay 10
echo ATH0 >COM1
delay 10
echo ATH1 >COM1
delay 60
echo ATH0 >COM1
goto start
:: ---- Exit to DOS (Only for FORCED Errorlevels!) ----
:: ---- This is an exit and The BBS is DOWN!! ----
:out
cd \fd
echo ath1 >com1
echo atm0 >com1
goto end
:: ---- Let's start the Midnight Maintenance ----
:midnight
echo ath1 >com1
cls
:: ---- I like noise ----
beep 440 4 587 2 1040 6
beep 440 4 587 2 1040 6
beep 440 4 587 2 1040 6
:: ---- This must run PRIOR to Midnight ----
c:
cd\ra\doors\racall
addtoday.exe c:\ra
cd\fd\file
if exist *.lzh del *.lzh
if exist *.tic del *.tic
::
:: ---- Set flag for Node 2 to stay down during Maint ----
:: ---- Set flag to check that Node 2 is down ----
:: ---- Also set flags to FORCE Node 2 down ----
::
cls
cd\ra
echo >maint.flg
echo >check.flg
echo >raxit2.65
::
:: ---- Node 2 Must be down to continue ----
::
:: ---- What follows is The Hole Nightly Maintenance ----
:: ---- this would be unique for every BBS but this ----
:: ---- has some nice examples in it for RA Utilities ---
::
:maint
cls
echo Waiting on Node 2 to go down .....
if exist c:\ra\check.flg goto maint
cls
echo Node 2 is down, Let's Rock & Roll......
delay 2
cd\ra\line1
ramsg link -clean -hudson
ramsg pack -overwrite -renumber -purge -delete -recover -link
rauser -s -p -m20 -d60
rafile clean g2 /km
rafile compress g2
rafile sort g2
cd\ra
dstat /g
cd\ra\raman
raman raman.cfg
del *.log
cd\cdrom
rafile filelist geofile.doc /bcomment.asc @area1.lst
rafile filelist thehole.doc /bcomment.asc @area.lst
move c:\cdrom\*.doc e:\files\misc
del *.log
e:
cd\files\misc
pkzip -f -o allfiles.zip thehole.doc
pkzip -f -o geofiles.zip geofile.doc
rafile update allfiles.zip 20 touchmod
rafile update geofiles.zip 20 touchmod
rafile update newfiles.zip 20 touchmod
del *.doc
del *.log
c:
cd\ra\doors
if exist *.log del *.log
if exist *.trn del *.trn
rmu
cd\ra\doors\uv
mdaily
cd\ra\doors\fishing
fishmant
if exist *.log del *.log
cd\ra\tradewar
if exist inuse.flg del inuse.flg
extern
if exist *.log del *.log
cd\ra\doors\isa
isapack /u
isa /f
isa /m
isapack /p
isa /p 60
isaclean
if exist *.log del *.log
cd\ra\doors\bre
if exist inuse.flg del inuse.flg
bre inbound
bre recon
bre planetary
if exist inuse.flg del inuse.flg
if exist log.txt del log.txt
cd\ra\doors\bre2
if exist inuse.flg del inuse.flg
bre inbound
bre planetary
brscores
if exist *.log del *.log
if exist log.txt del log.txt
cd\ra\doors\race
pitmast
if exist *.log del *.log
cd\fd\fmail
if exist *.log del *.log
cd\ra\line3
if exist *.log del *.log
cd\fd\nodelist
if exist c:\fd\nodelist\nodediff.* goto merge
cd\ra
del maint.flg
del raxit2.65
cd\fd
del fdxit.65
cd\ra\line1
cls
beep 440 4 587 2 1040 6
beep 440 4 587 2 1040 6
beep 440 4 587 2 1040 6
goto start
:: ---- Merge the Nodelists while Node 2 is down ----
:: ---- If there was no Node 2 this could be done ---
:: ---- when NODEDIFF is processed (see NEWNODE) ----
:merge
sysnl merge nodelist nodediff c
cd c:\fd
fdnc /f
del c:\fd\file\nodediff.*
cd \ra
ranode fdnet.pvt
del maint.flg
del raxit2.65
cd\fd
del fdxit.65
cd\ra\line1
cls
beep 440 4 587 2 1040 6
beep 440 4 587 2 1040 6
beep 440 4 587 2 1040 6
goto start
:: --- And if ALL Else fails ----
:end
echo The Hole Line 1 is now down!
exit
How to run Node 2 with RemoteAccess
used with above Batch file.
@echo off
rem echo on
cls
::
:: The Hole BBS (Node 2)
:: Written by Sysop: Stu Grant
::
:: This BAT file is VERY similar to the Node 1 BAT file EXCEPT that it
:: runs NO maintenance and instead waits for Node 1 to finish it's job
:: before resuming. The process of taking down both Nodes (and making
:: SURE they are down) is quite easy (see the section on WAIT).
::
:: Here it is!
::
:: ---- Let's Start The BBS (Node 2) ----
:: ---- Fire up the Fossil for a DV Window -----
:: c:\ra\bnu.com /f+ /m-
:start
c:
echo ath0 >com2
cls
echo Firing up The Hole (Node 2) .....
:: ---- Let's set the environments
cd \ra\line2
set ra=c:\ra
set dszlog=c:\ra\dsz.log
set dszport=1
:: ---- Condition checks and actions ----
cd c:\fd\file
if exist c:\ra\line2\dsz.log del \ra\line2\dsz.log
if exist c:\fd\file\*.tic del *.tic
:: ---- Special program to put Last BBS caller on FD screen ----
::
:: cd\ra\line2
:: ra2fd -rc:\ra\lastcall.bbs -fc:\fd\lastcall.fd -a1:275/72 -t
::
:: ---- Fire up RA and Shell to FrontEnd Mailer ----
cd\ra\line2
ra -n2 -m\fd\fd.exe*m -e20
:: ---- Errorlevels to trap for action ----
if errorlevel 65 goto wait
if errorlevel 38 goto unpackmail
if errorlevel 20 goto start
if errorlevel 15 goto reboot
if errorlevel 10 goto out
if errorlevel 5 goto both
if errorlevel 4 goto echo
if errorlevel 3 goto net
if errorlevel 2 goto restart_ra
if errorlevel 1 goto start
if errorlevel O goto start
:: ---- Next Line in case an errorlevel was missed -----
goto start
:: ---- Log back on after type 15 with errorlevel, See docs! ----
:restart_ra
echo ath0 >com2
c:
cd \ra\line2
ra -r -g -e20
if errorlevel 65 goto wait
if errorlevel 38 goto unpackmail
if errorlevel 20 goto start
if errorlevel 15 goto reboot
if errorlevel 10 goto out
if errorlevel 5 goto both
if errorlevel 4 goto echo
if errorlevel 3 goto net
if errorlevel 1 goto start
if errorlevel O goto start
goto start
:: ---- Scan for Mail after Logoff if message base changed ----
:echo
echo ath1 >com2
fmail scan
goto start
:: ---- Scan for Mail after Logoff if message base OR folder has changed ----
:both
echo ath1 >com2
fmail scan
goto start
:: ---- Export NetMail to folder ----
:net
echo ath1 >com2
cd \ra
mbutil export
goto start
:: ---- Unpack and Toss incomming Mail packets ----
:unpackmail
echo ath1 >com2
cd c:\fd\fmail
fmail toss import
goto start
:: ---- This attempts to handle INIT failures by FrontDoor ----
:: ---- Since I run under OS/2 I must attempt to re-init ----
:: ---- the modem. Under DOS or DV I would run a COLD BOOT ---
:: ---- program. Such as REBOOT.EXE
:reboot
echo ath0 >com2
delay 10
echo ath1 >com2
delay 10
echo ath0 >com2
delay 10
echo ath1 >com2
delay 60
echo ath0 >com2
goto start
:: ---- Exit to DOS (Only for FORCED Errorlevels!) ----
:: ---- This is an exit and The BBS is DOWN!! ----
:out
cd \fd
echo ath1 >com2
echo atm0 >com2
goto end
:: ---- Node 2 must be down while Node 1 runs Maint AND
:: ---- Node 1 will NOT begin until CHECK.FLG is deleted AND
:: ---- Node 2 will NOT come back up until MAINT.FLG is deleted.
:: ---- Node 2 should be taken down by an EVENT but we will
:: ---- have Node 1 force it down with RAXITn.e just in case.
:wait
cls
echo ath1 >com2
echo The Hole Node 2 is going down.....
delay 5
cd\ra
if exist c:\ra\check.flg del c:\ra\check.flg
:: now Node 1 can take off....
:: ---- If the above condition was NOT met then Node 1 is NOT ----
:: ---- down then Node 2 would simply fire back up, This is not---
:: ---- a problem as Node 1 will force Node 2 down when it goes --
:: ---- down. This MAY occur due to a quirk in the timing of ---
:: ---- the events. (That is why we have the force option :)
::
:: ---- Once CHECK.FLG is deleted Node 1 can do its thing and ----
:: ---- Node 2 enters a wait (loop) per below ----
:loop
cls
echo Node 1 is doing its Maintenance thing, gotta wait dude....
if exist c:\ra\maint.flg goto loop
goto start
:: ---- And if all else fails ----
:end
echo The Hole BBS is down on Node 2 !
exit
How to run a local 3rd node with RemoteAccess.
@echo off
::
:: ---- The Hole BBS (Local Node 3) ----
:: ---- Written by Sysop: Stu Grant ----
::
::
:: ---- This is the BAT file that runs The Hole Local Node ----
:: ---- The only function besides the board is the scan for ---
:: ---- mail at logoff and of course this Node shuts down -----
::
:start
c:
echo Firing up Stu's private line .....
cd \ra\line3
set dszlog=c:\ra\dsz.log
set ra=c:\ra
set fd=c:\fd
if exist c:\ra\dsz.log del \ra\dsz.log
ra -l -n3 -e20
if errorlevel 20 goto out
if errorlevel 10 goto out
if errorlevel 5 goto echo
if errorlevel 4 goto both
if errorlevel 3 goto net
if errorlevel O goto out
goto start
:echo
fmail scan
goto out
:both
fmail scan
goto out
:net
cd \ra
mbutil export
goto out
:out
echo Later days Stu .......
delay 3
exit
░▒▓█ D'Bridge Setup with RemoteAccess █▓▒░
Here's how I do NetMail with RA and D'Bridge =only=... no other tossers or
utilities needed... With this method I can write NetMail in RA =or= in
DB's Editor:
Here's a way to do NetMail with RA and D'Bridge 1.5x =only=... no
other tossers or utilities needed. With this method you can write
NetMail in RA =or= in DB's Editor:
1. Call EXEBBS.BAT from your DOS AUTOEXEC.BAT, i.e. C:\RA\EXEBBS.BAT
2. The following is an edited (to save space) EXEBBS.BAT:
:START
CD\RA
RA -P -M\DB\DB.EXE*M
If Errorlevel 10 goto EXIT
If Errorlevel 5 goto NET_ECHO
If Errorlevel 4 goto ECHO_ONLY
If Errorlevel 3 goto NET_ONLY
If Errorlevel 2 goto EXIT
Goto AFTER_2
:NET_ECHO
ECHO > C:\DB\DBRIDGE.RSN
ECHO > C:\DB\DBRIDGE.RSE
goto AFTER_2
:ECHO_ONLY
ECHO > C:\DB\DBRIDGE.RSE
goto AFTER_2
:NET_ONLY
ECHO > C:\DB\DBRIDGE.RSN
goto AFTER_2
:AFTER_2
Goto START
:EXIT
3. In D'Bridge create a NetMail echomail area (#14 for example here) and
use the QuickBBS format. D'Bridge will automatically create a #0 NetMail
area. Go to DBee's EDITOR>ECHOmail areas>LOCAL/ECHOMAIL area manager>
Area # 14
Storage: QuickBBS
QuickBBS area: 14
Area type: Echomail
Quick directory path: C:\RA\MSGBASE\
4. Go to D'Bridge CONFIG>Directory paths>
Network mail storage: QuickBBS
QuickBBS area number: 14
5. Go to D'Bridge CONFIG>Packet/Mail control>
Inbound mail handling? Automatic
6. Go to D'Bridge ADVANCED>BBS configuration>
DOS commands for BBS:
echo EXEBBS *P *B *T *C > C:\RA\DOBBS.BAT
XU Fifo:15 Port:0:On Lock:0:38400:8N1
*X
(The above example uses Ray Gwinn's X00150 fossil to lock com ports)
7. Make sure your RA NetMail Message Area number and the DB NetMail
Message Area number are the same and that in RACONFIG>Manager>Msg
areas> you set =Type= to NetMail.
This should be a good starting point and gives a pretty good idea how well
RA and DBee can work together.
░▒▓█ InterMail setup with RemoteAccess █▓▒░
Rem My Ra Runtime Batch File for (Line_1) 5-Apr-94
@Echo Off
:Start
If exist C:\Qmx1\*.pkt copy C:\Qmx1\*.pkt C:\IM1\Secure
If exist C:\Qmx1\*.pkt Dstamp C:\IM1\Sema\Imexit02.108
If exist C:\Qmx1\*.pkt Del C:\Qmx1\*.pkt
If exist C:\Ra\Useron.bbs Del C:\Ra\Useron.bbs
CD\IM1\Mail
Echo Y|Zerokill %1
C:
Cd\Ra\Line1
Cd\IM1
IM /#1 /NOEMS
If Errorlevel 249 Goto HMB_Purge
If Errorlevel 110 Goto Maintenance
If Errorlevel 108 Goto Unpackmail
If Errorlevel 107 Goto Monthly
If Errorlevel 105 Goto Net&Echo
If Errorlevel 100 Goto Nodediff
If Errorlevel 50 Goto 28800_Baud
If Errorlevel 49 Goto 26400_Baud
If Errorlevel 48 Goto 24000_Baud
If Errorlevel 47 Goto 21600_Baud
If Errorlevel 46 Goto 19200_Baud
If Errorlevel 45 Goto 16800_Baud
If Errorlevel 44 Goto 14400_Baud
If Errorlevel 43 Goto 9600_Baud
If Errorlevel 42 Goto 2400_Baud
If Errorlevel 41 Goto 1200_Baud
If Errorlevel 40 Goto 300_Baud
If Errorlevel 32 Goto Local
If Errorlevel 10 Goto End
If Errorlevel 8 Goto IM_Already
:28800_Baud
Cd\Ra\Line1
Wait 10
C:\Ra\Ra.exe -B28800 -N1 -E20 -NOEMS
Goto After_BBS
:26400_Baud
Cd\Ra\Line1
Wait 10
C:\Ra\Ra.exe -B26400 -N1 -E20 -NOEMS
Goto After_BBS
:24000_Baud
Cd\Ra\Line1
Wait 10
C:\Ra\Ra.exe -B24000 -N1 -E20 -NOEMS
Goto After_BBS
:21600_Baud
Cd\Ra\Line1
Wait 10
C:\Ra\Ra.exe -B21600 -N1 -E20 -NOEMS
Goto After_BBS
:19200_Baud
Cd\Ra\Line1
Wait 10
C:\Ra\Ra.exe -B19200 -N1 -E20 -NOEMS
Goto After_BBS
:16800_Baud
Cd\Ra\Line1
Wait 10
C:\Ra\Ra.exe -B16800 -N1 -E20 -NOEMS
Goto After_BBS
:14400_Baud
Cd\Ra\Line1
Wait 10
C:\Ra\Ra.exe -B14400 -N1 -E20 -NOEMS
Goto After_BBS
:9600_Baud
Cd\Ra\Line1
Wait 10
C:\Ra\Ra.exe -B9600 -N1 -E20 -NOEMS
Goto After_BBS
:2400_Baud
Cd\Ra\Line1
Wait 10
C:\Ra\Ra.exe -B2400 -N1 -E20 -NOEMS
Goto After_BBS
:1200_Baud
Cd\Ra\Line1
Wait 10
C:\Ra\Ra.exe -B1200 -N1 -E20 -NOEMS
Goto After_BBS
:300_Baud
Cd\Ra\Line1
Wait 10
C:\Ra\Ra.exe -B300 -N1 -E20 -NOEMS
Goto After_BBS
:Local
Echo ATH1M0 >COM1
Cd\Ra\Line1
C:\Ra\Ra.exe -L -N1 -E20 -NOEMS
Cd\IM1
Goto Net&Echo
:After_BBS
Cd\Ra
Copy C:\Ra\Line1\Ra.log+C:\Ra\Line2\Ra.log C:\Ra\Both.log
Download
Upload
Del C:\Ra\Both.log
If Errorlevel 20 Goto Start
If Errorlevel 5 Goto Net&Echo
If Errorlevel 4 Goto Echo
If Errorlevel 3 Goto Net
Goto Start
:Unpackmail
Dstamp C:\IM1\Sema\Imexit02.108
Goto Start
:Net&Echo
CD\IM2
Echo ATH1M0 >COM1
Dstamp C:\IM1\Sema\Imexit02.105
Goto Start
:Echo
CD\IM2
Echo ATH1M0 >COM1
Dstamp C:\IM1\Sema\Imexit02.105
Goto Start
:Net
CD\IM2
Echo ATH1M0 >COM1
Dstamp C:\IM1\Sema\Imexit02.105
Goto Start
:Restart
Ra -R -E0 -N1 -NOEMS
Cd\IM1
Goto Start
:IM_Already
Exit
:End
░▒▓█ How to Setup BinkleyTerm and RemoteAccess using OS/2 █▓▒░
How to run an OS/2 Mailer with a DOS BBS Program
------------------------------------------------
Disclaimer
----------
Standard, but required. This textfile is meant for advice only, and the
author is not responsible for any damages that occur through the use of this
document. If what you have now is in one piece, and using this textfile leaves
you with two broken pieces, I suggest you go out and buy an economy size tube of
KrazyGlue<tm> 8-)
Notes
-----
In this document, when I have listed lines from my configuration files,
each line is preceded by a '>' character. Do not type this in, it's just to
show that this is a file line, not part of my babbling 8-)
Now, on to the Good Stuff
-------------------------
What will this textfile allow you to do ? Specifically, coach you in
setting up BinkleyTerm v2.50EE with RemoteAccess v2.01. Hopefully, the idea
will be usable with any OS/2 Mailer (or Comm program for that matter) and DOS
BBS.
My configuration (i.e. what I _know_ it works with)
- BinkleyTerm/2 v2.50EE
- RemoteAccess v2.01
- SIO (SIO, VSIO, VX00) v1.20
- 4OS2-32 v1.11
How to do it
------------
The important thing to do is remove protection from the port you will be
using. OS/2 built in protection is what comes up and says "Sharing violation on
COMx". SIO allows you to remove protection for a port (although it's not
documented). I checked with Ray Gwinn that it was alright to document it here,
so this is how : In CONFIG.SYS, put a dash (-) in the 5th position of the comm
port parameters. If you are not using the 4th parameter, put an extra comma to
space it out correctly. For example, my setup using COM2 locked at 38400
without protection is :
> DEVICE=C:\OS2\EXTRAS\SIO.SYS (COM2:38400,,,-)
Load VX00.SYS as usual after this. This is all that's required for CONFIG.SYS
Now, in Binkley.Cfg, I use BBSSpawn. My SPAWNBBS.CMD contains this :
> echo EXEBBS %2 2 %4 %5 > D:\RA\DOBBS.BAT
> start "RemoteAccess" /FG /FS /WAIT /DOS=C:\OS2\4DOS\RA.INI D:\RA\DOBBS.BAT
You'll notice that this echoes the parameters %BPS% %PORT% %EVENT TIME%
%EXTENDED CONNECT% into my \RA\DOBBS.BAT file. I'm a recent FrontDoor convert,
and using this produces a DOBBS.BAT that is compatible with FD's. Also, notice
that I am forcing port 2 into the batch file. This is because BT passes the
Port Handle that OS/2 assigns, which is not the physical port number. If you
are running singleline, just force the port as I have. If not, use a %PORT
environment variable to do the same task.
You'll notice I'm using 4OS2 in the above example. The reason is that
4OS2-32 (not the 16 bit version) allows you to start a DOS session with a
specific set of settings, similar to the way you set up an object's DOS settings
on the workplace shell. The file C:\OS2\4DOS\RA.INI contains the following :
> DOS_SHELL=C:\OS2\4DOS\4DOS.COM C:\OS2\4DOS @C:\OS2\4DOS\4DOSRA.INI
> DOS_DEVICE=C:\OS2\EXTRAS\VX00.SYS
> DOS_AUTOEXEC=C:\OS2\4DOS\BBSSTART.BAT
> SIO_ALLOW_ACCESS_COM2=1
> EMS_MEMORY_LIMIT=2048
> XMS_MEMORY_LIMIT=2048
> INT_DURING_IO=1
This allows me to load VX00.SYS when the DOS session is spawned from the
Binkley window. The /WAIT switch on the command line makes the session wait
until the DOS session closes to restart Binkley. This eliminates the need to
use semaphores as detailed in the MAGIC package that has been available for some
time. If you don't want or can't use 4OS2-32, you can try using HSTART or
STARTD, both of which allow you to start a DOS session with specific DOS
sessions. Individual results may vary.
I think we need a subtitle here...
----------------------------------
The thing that has caused me (and other people) problems in the past is
with regard to SIO. I don't fully understand it, but I'll try to put it as best
I can. SIO has some part of it to handle the communication with DOS sessions.
This part is not initialized when SIO loads, presumably to reduce overhead on
systems not using DOS communications. The part is initialized the first time
that VX00.SYS is loaded. The problem is that if there is a carrier present when
this part is woken up, something happens. The DOS app can send data out the
port, but nothing can travel inbound.
The solution to this problem has been provided by Ray Gwinn, author of SIO.
I have spoken with him regarding this, and I'm not sure if my report helped him
track down the cause of the problem, but the following excerpt from SIO
v1.21k's READ.ME file explains :
The method in which the SIO_Mode setting are implemented has
been changed. These settings specify only the initial mode
settings to use for a DOS session. Changes made to the mode
(via a MODE or other command) within the DOS session are no
longer lost. The SIO_Mode settings isolate the DOS VDM's
mode from that of OS/2 sessions in all but one case. The
one case is when the port is already opened when DOS first
accesses it. In this one case, the SIO_Mode settings are
not applied. Except for this one case, one should view OS/2
as having its mode settings and DOS sessions as having an
independent group of mode settings.
As you can see, the problem lied in SIO trying to apply the specified Mode
settings to an opened port. You need SIO v1.21k or higher (a beta version, it
is currently available as SIOBETA, but there may well be a release version
implementing the same fix by the time you read this) to perform this little
trick.
Other Versions of Programs
--------------------------
I am pretty sure that this will work using Standard BinkleyTerm/2, but I haven't
yet tried. As long as your DOS BBS program runs well in a straight all DOS
combination under OS/2, it should work under this method. For SIO, older
versions than v1.20 should work, but newer versions (usually) provide better
performance.
Th-Th-Th-That's All Folks!
--------------------------
Well, that's how it's done. It works here for me, and I hope this will allow
people to do the same. For further information, contact me via netmail at one
of the following addresses :
1:250/301 @ fidonet
18:105/301 @ zyxelnet
40:6482/301 @ ibmnet
81:416/236 @ nanet
File Request Names
------------------
BinkleyTerm - BTOS2_258.ARJ for BinkleyTerm/2 v2.58 wide beta. Michael
Buenter has asked that BT Extended not be distributed, so I
don't have it available. BT/2 v2.58 has folded in a lot of
Michael's code though, so you may be pleasantly surprised.
SIO - SIO120.ARJ for the latest version as of this writing. SIO*.*
should get you just the latest version, as I keep only the latest
online (exception: a beta archive may be out without
documentation files, so I might have two)
4OS2/32 - 4OS232.ARJ for the latest version (v1.11 as of this writing).
v2.00 has been announced, but isn't yet shipping.
Thanks
------
Thanks to Matthew Stein (1:250/701) for getting me involved with OS/2.
Without his help I probably never would have switched.
No Thanks to Matthew Stein (1:250/701) for telling me that every time I had a
problem, it was "the fault of that stupid DOS BBS and you should just switch
to Max/2 anyway" 8-)
And a word of closing
---------------------
Regarding SIO - if there is one program you're going to register for your OS/2
BBS system, make it this one. Take a minute to think where we'd be without Ray
Gwinn and SIO. Can you say "CRC Error" ? Knew you could. Ray gave us X00
without charge, and now he's asking what I consider a paltry sum for
SIO/VSIO/VX00 ($25 US). If you want Ray to continue to improve this fine
driver, we have to show support for him. Thank you.
James FitzGibbon
1:250/301@fidonet.org
░░▒▒▓▓ FRONTEND.Q&A ▓▓▒▒░░
Total Lines: 1172 Total Size: 28k